Невидимость документа

[ishayahu]

Подскажите, пожалуйста, какое свойство отвечает за невидимость документа? Мне надо открыть документ, внести в него значения, отправить на печать и закрыть. При этом мне не надо, чтобы открывалось лишнее окно. Как можно сделать документ (окно) невидимым?

[Рыбка Рио]

Чтобы открыть документ невидимым,

Код Выделить Развернуть


DocURL=convertToURL("/path/to/file, например, C:\123.ods")
Dim p(0) as new com.sun.star.beans.PropertyValue
   p(0).Name = "Hidden"
   p(0).Value = TRUE
   oDoc = starDesktop.loadComponentFromURL(DocURL, "_default", 0, p())

Чтобы открытый документ сделать невидимым:

Код Выделить Развернуть

oDoc.CurrentController.Frame.ContainerWindow.setVisible(FALSE)

[ishayahu]

С первым вариантом перестает печататься документ, а со вторым все в порядке( В чем может быть дело?

[вложение удалено Администратором]

[JohnSUN]

Питоньяк, когда рассказывал про параметр Hidden для loadComponentFromURL, предупредил, что большая часть сервисов при таком способе открытия документа просто не загружается и не будет доступна. Какие именно он не уточнил, но, похоже, печать относится именно к этим, пропускаемым...

[ishayahu]

А Питоньяк это кто?
И нельзя ли загрузить эти сервисы принудительно?

[RFJ]

Сервисы, свойства, методы, интерфейсы документа Hidden можно изучать обычным Xray:

Код Выделить Развернуть

If (Not GlobalScope.BasicLibraries.isLibraryLoaded("XrayTool")) Then GlobalScope.BasicLibraries.LoadLibrary("XrayTool")
 Xray oDoc

[Рыбка Рио]

С первым вариантом перестает печататься документ

Вот такой код у меня работает (печатается):

Код Выделить Развернуть

Sub Main
DocURL=convertToURL("/home/user/Рабочий стол/Без имени 1.odt")
Dim p(0) as new com.sun.star.beans.PropertyValue
  p(0).Name = "Hidden"
  p(0).Value = TRUE
  oDoc = starDesktop.loadComponentFromURL(DocURL, "_default", 0, p())
  oDoc.print(Array())
  Wait 5000
  oDoc.close(True)
End Sub

[JohnSUN]

Эндрю Питоньяк это такой очень умный человек, который на макросах для OpenOffice.org "собаку съел"
Есть и несколько переведенных на русский язык вариантов этой книги... Что-то, ссылку сходу найти не могу... Да это и не важно, пожалуй. Там все-равно не столько английский язык, сколько чистый бэйсик, в переводе не нуждается

[вложение удалено Администратором]

[Рыбка Рио]

И такой тоже код работает:

Код Выделить Развернуть

Sub Main
DocURL=convertToURL("/home/user/Рабочий стол/Без имени 1.odt")
Dim p(0) as new com.sun.star.beans.PropertyValue
  p(0).Name = "Hidden"
  p(0).Value = TRUE
  oDoc = starDesktop.loadComponentFromURL(DocURL, "_default", 0, p())
 
Dim PrintProperties(0) as new com.sun.star.beans.PropertyValue  
  PrintProperties(0).Name = "Wait"
PrintProperties(0).Value = True
oDoc.print(PrintProperties())
  'oDoc.print(Array())
 
'   Wait 2000
  oDoc.close(True)
End Sub

[Рыбка Рио]

Разницы между первым и вторым методом вроде бы нет. Со скрытыми документами даже dispatcher работает, только там нужно немного по-другому определять Frame, вот такая функция:

Код Выделить Развернуть

Function GetDocumentFrame( oDoc As Object ) As Object
Dim oFrame As Object
If oDoc.supportsService( "com.sun.star.document.OfficeDocument" ) Then
oCtrl = oDoc.getCurrentController()
oFrame = oCtrl.getFrame()
ElseIf HasUnoInterfaces( oDoc, "com.sun.star.frame.XController" ) Then
oCtrl = oDoc
oFrame = oCtrl.getFrame()
ElseIf HasUnoInterfaces( oDoc, "com.sun.star.frame.XFrame" ) Then
oFrame = oDoc
EndIf

GetDocumentFrame() = oFrame
End Function

Так что код с диспатчером выглядит так:

Код Выделить Развернуть

dispatcher.executeDispatch(GetDocumentFrame(oDoc), ".uno:Paste", "", 0, Array())

[ishayahu]

э... вдруг заработало... возможно помогла снятая галочка "печатать только выбранные листы"

[ishayahu]

Печатает в любом случае, и с галочкой, и без нее. Почему - не знаю Но, работает
Видимо, можно закрывать.